//  5040 Surprise Minor (24m)
//  Composed by (1-4) J S Warboys SU0403
//  (1-4) Allendale, Annable's London, Bacup, Bamborough, Berwick, Beverley, Bourne, Cambridge, Durham, Hexham, Hull, Ipswich, Lightfoot, Netherseale, Norfolk, Norwich, Primrose, Rossendale, Stamford, Surfleet, Warkworth, Wearmouth, Westminster, York (5) Beverley (6) Netherseale (7) Cambridge

6 bells;
7 extents;

lh = "\";

start  = "  @ \";
block_finish = lh, "\n";

p2lh  = +2;
p2lhv = +2, "\n  @ \"; //Print row for plain course end
p6lh  = +6;
p6lhv = +6, "\n  @ \"; //Print row for plain course end
blh   = +4, "\n- @ \";

lh2 = (p = lh=p2lh), (b = lh=blh), (ce = lh=p2lhv), (lh=p2lh);
lh6 = (p = lh=p6lh), (b = lh=blh), (ce = lh=p6lhv), (lh=p6lh);

Cam_over = (o_f = +-3-4), (o_b = +4-3-);
Nor_over = (o_f = +-34-4), (o_b = +4-34-);

Cam_under = (u_f = +3-4-),   (u_b = +-4-3);
Nor_under = (u_f = +3-34-),  (u_b = +-34-3);
Sur_under = (u_f = +3.4-2),  (u_b = +2-4.3);
Wel_under = (u_f = +3.4-34), (u_b = +34-4.3);
Lon_under = (u_f = +3.4-4),  (u_b = +4-4.3);
Wes_under = (u_f = +3-2-),   (u_b = +-2-3);
All_under = (u_f = +3.2-2),  (u_b = +2-2.3);
Bam_under = (u_f = +3.2-4),  (u_b = +4-2.3);

hl1 = (hl = +1);
hl3 = (hl = +3);
hl5 = (hl = +5);

lead = o_f, +-2-, u_f, hl, u_b, +-2-, o_b;

Bo=lh, Cam_over, Nor_under, hl3, lead, lh2, "Bo \";
Hu=lh, Cam_over, Nor_under, hl3, lead, lh6, "Hu \";
Ip=lh, Cam_over, Cam_under, hl1, lead, lh2, "Ip \";
Nf=lh, Cam_over, Cam_under, hl1, lead, lh6, "Nf \";
Cm=lh, Cam_over, Cam_under, hl5, lead, lh2, "Cm \";
Pr=lh, Cam_over, Cam_under, hl5, lead, lh6, "Pr \";
Su=lh, Cam_over, Sur_under, hl5, lead, lh2, "Su \";
He=lh, Cam_over, Sur_under, hl5, lead, lh6, "He \";
Du=lh, Cam_over, Wel_under, hl1, lead, lh2, "Du \";
Bv=lh, Cam_over, Wel_under, hl5, lead, lh2, "Bv \";
Bk=lh, Cam_over, Wel_under, hl5, lead, lh6, "Bk \";
Yo=lh, Cam_over, Lon_under, hl3, lead, lh2, "Yo \";

Ws=lh, Nor_over, Wes_under, hl3, lead, lh2, "Ws \";
No=lh, Nor_over, Nor_under, hl1, lead, lh6, "No \";
Ad=lh, Nor_over, All_under, hl3, lead, lh2, "Ad \";
Bm=lh, Nor_over, Bam_under, hl5, lead, lh2, "Bm \";
Bc=lh, Nor_over, Bam_under, hl5, lead, lh6, "Bc \";
Ne=lh, Nor_over, Cam_under, hl3, lead, lh2, "Ne \";
Ab=lh, Nor_over, Cam_under, hl3, lead, lh6, "Ab \";
Wk=lh, Nor_over, Sur_under, hl3, lead, lh6, "Wk \";
Wm=lh, Nor_over, Wel_under, hl1, lead, lh2, "Wm \";
St=lh, Nor_over, Wel_under, hl1, lead, lh6, "St \";
Lf=lh, Nor_over, Lon_under, hl3, lead, lh2, "Lf \";
Ro=lh, Nor_over, Lon_under, hl3, lead, lh6, "Ro \";

block_one =   No,Ne,Ad,Ws,b,Ad,b,Ad,b,Wk,b,Wm,Lf,Bm,Wm,b,Ab,Wk,Ab,Ro,Ro,b,St,Bc,St,b,Wk,ce,
	    2(No,Ne,Ws,Ws,b,Ad,b,Ad,b,Wk,b,Wm,Lf,Bm,Wm,b,Ab,Wk,Ab,Ro,Ro,b,St,Bc,St,b,Wk,ce); 
block_two = 3(Ip,Bo,Ip,Cm,b,Yo,Cm,Du,Du,b,Hu,Pr,Nf,Nf,b,Du,b,Bv,Bk,Bk,b,He,Su,Su,b,Yo,b);

// Last three extents
plain = +2;
bob = +4;

W = repeat( m, {/*6/:  bob, break; plain} )
H = repeat( m, {/*6?/: bob, break; plain} )

WHW_end = repeat(m, plain, {/123456/: break})

extent_5 = (m = Cam_over, Wel_under, hl1, lead), 3(W,H,W), WHW_end;

extent_6 = (m = Nor_over, Cam_under, hl3, lead), 3(W,H,W), WHW_end;

extent_7 = (m = Cam_over, Cam_under, hl5, lead), 3(W,H,W), WHW_end;

prove block_one, block_two, block_finish, extent_5, extent_6, extent_7;